Viewing is open to everyone. Downloading and starring need a GitHub sign-in.
Sign in with GitHub
build.gradle.kts
v0.1.0-build.85
Latest
Commit ede38f5
Sign in with GitHub to download. Each download is recorded with your GitHub username.
| 1 | // Root build: shared publication settings for every module. |
| 2 | plugins { |
| 3 | alias(libs.plugins.android.library) apply false |
| 4 | alias(libs.plugins.kotlin.android) apply false |
| 5 | alias(libs.plugins.kotlin.compose) apply false |
| 6 | } |
| 7 | |
| 8 | /** The SDK version is the repository's VERSION file (e.g. 0.1.0-build.65). */ |
| 9 | val ckeyVersion: String = rootDir.resolve("../../VERSION").readText().trim() |
| 10 | require(Regex("^0\\.[0-9]+\\.[0-9]+(-(build|dev)\\.[0-9]{1,6})?$").matches(ckeyVersion)) { |
| 11 | "VERSION '$ckeyVersion' does not match the CKey version scheme" |
| 12 | } |
| 13 | |
| 14 | subprojects { |
| 15 | group = "org.openckey" |
| 16 | version = ckeyVersion |
| 17 | |
| 18 | plugins.withId("maven-publish") { |
| 19 | afterEvaluate { |
| 20 | extensions.configure<PublishingExtension> { |
| 21 | publications { |
| 22 | create<MavenPublication>("release") { |
| 23 | from(components["release"]) |
| 24 | groupId = "org.openckey" |
| 25 | artifactId = project.name |
| 26 | version = ckeyVersion |
| 27 | pom { |
| 28 | name.set(project.name) |
| 29 | description.set(project.description) |
| 30 | url.set("https://github.com/clearkeysolutions/ckey") |
| 31 | licenses { |
| 32 | license { |
| 33 | name.set("MIT License") |
| 34 | url.set("https://opensource.org/licenses/MIT") |
| 35 | distribution.set("repo") |
| 36 | } |
| 37 | } |
| 38 | developers { |
| 39 | developer { |
| 40 | id.set("clearkeysolutions") |
| 41 | name.set("ClearKey Solutions") |
| 42 | url.set("https://github.com/clearkeysolutions") |
| 43 | } |
| 44 | } |
| 45 | scm { |
| 46 | url.set("https://github.com/clearkeysolutions/ckey") |
| 47 | connection.set("scm:git:https://github.com/clearkeysolutions/ckey.git") |
| 48 | developerConnection.set("scm:git:ssh://git@github.com/clearkeysolutions/ckey.git") |
| 49 | } |
| 50 | } |
| 51 | } |
| 52 | } |
| 53 | // No credentials here. CI publishes to a local directory; release |
| 54 | // automation adds its own repository (and signing) from secrets. |
| 55 | repositories { |
| 56 | maven { |
| 57 | name = "local" |
| 58 | url = uri(rootProject.layout.buildDirectory.dir("maven")) |
| 59 | } |
| 60 | } |
| 61 | } |
| 62 | } |
| 63 | } |
| 64 | } |